# Maintainer: Christoph Reiter <reiter.christoph@gmail.com>

pkgname=libbsd
pkgver=0.12.2
pkgrel=1
pkgdesc='Provides useful functions commonly found on BSD systems like strlcpy()'
arch=('i686' 'x86_64')
url="https://libbsd.freedesktop.org"
msys2_references=(
  "cpe: cpe:/a:freedesktop:libbsd"
)
license=('custom')
depends=('libmd')
makedepends=("gcc" "autotools" "make")
source=("https://libbsd.freedesktop.org/releases/$pkgname-$pkgver.tar.xz"{,.asc}
        "cygwin-build.patch")
sha256sums=('b88cc9163d0c652aaf39a99991d974ddba1c3a9711db8f1b5838af2a14731014'
            'SKIP'
            '30f5b5b47a80f4be0da69c1004adb0f49ff2465ed1dc783650ee055978aaf904')
validpgpkeys=('4F3E74F436050C10F5696574B972BF3EA4AE57A3') # Guillem Jover

prepare() {
  cd "${pkgname}-${pkgver}"

  patch -p1 -i "${srcdir}/cygwin-build.patch"

  autoreconf -vfi
}

build() {
  cd "$pkgname-$pkgver"

  ./configure \
    --build="${CHOST}" \
    --prefix=/usr
  make
}

check() {
  cd "$pkgname-$pkgver"
  make check
}

package() {
  cd "$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install
  install -D -m644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
