
_realname=findutils
pkgbase=mingw-w64-uutils-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-uutils-${_realname}")
pkgver=0.8.0
pkgrel=1
pkgdesc="Rust rewrite of findutils (mingw-w64)"
arch=('any')
mingw_arch=('ucrt64' 'clang64' 'clangarm64')
url="https://github.com/uutils/findutils"
msys2_repository_url="${url}"
msys2_references=(
)
license=('spdx:MIT')
depends=("${MINGW_PACKAGE_PREFIX}-oniguruma")
makedepends=("${MINGW_PACKAGE_PREFIX}-rust"
             "${MINGW_PACKAGE_PREFIX}-pkgconf")
source=("${url}/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('932f153d256f7a4cf40255a948689bf59a10f14c8804151817ab50fa1b46429a')

prepare() {
  cd "${_realname}-${pkgver}"
  cargo fetch --locked --target "${RUST_CHOST}"
}

build(){
  cd "${_realname}-$pkgver"
  export RUSTONIG_DYNAMIC_LIBONIG=1
  cargo build --release --frozen
}

package() {
  cd "${_realname}-$pkgver"
  install -Dm755 "target/release/find" "${pkgdir}${MINGW_PREFIX}/bin/uu-find"
  install -Dm755 "target/release/xargs" "${pkgdir}${MINGW_PREFIX}/bin/uu-xargs"
  install -Dm644 LICENSE -t "${pkgdir}${MINGW_PREFIX}/share/licenses/uutils-${_realname}"
}
