# Maintainer: Christoph Reiter <reiter.christoph@gmail.com>

_realname=tzdata
pkgbase=mingw-w64-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
pkgver=2026b
pkgrel=1
pkgdesc="Sources for time zone and daylight saving time data (mingw-w64)"
arch=('any')
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64')
url="https://www.iana.org/time-zones"
license=('custom: public domain')
makedepends=('tzcode')
options=('!emptydirs')
source=(https://www.iana.org/time-zones/repository/releases/${_realname}${pkgver}.tar.gz{,.asc}
        https://www.iana.org/time-zones/repository/releases/tzcode${pkgver}.tar.gz{,.asc})
sha512sums=('a44882258c0a7fbe587e8b73d6bb3cd5be7d4788976ea742adbbf176eb3b33e5bd7d1714b2fffe2972b1a42e7335eac39ed0bd63e819bb421550f8cae1df4f2f'
            'SKIP'
            '55b44d52a83c9db151be32c3d78376ea7f9d4311ef15ed6fe34b855b08fc546531e51309d178d9c175a6d5d7d0b058440e45a55d200ca8925e3798dac9bc739f'
            'SKIP')
validpgpkeys=('7E3792A9D8ACF7D633BC1588ED97E90E62AA7E34') # Paul Eggert <eggert@cs.ucla.edu>

_timezones=('africa' 'antarctica' 'asia' 'australasia'
           'europe' 'northamerica' 'southamerica'
           'etcetera' 'backward' 'factory')

build() {
  cd "${srcdir}"

  touch version  # avoid it re-sourcing from git in case anything is patched above
  make tzdata.zi leapseconds
}

package() {
  cd "${srcdir}"

  # install tzdata stuff
  zic -b fat -d "${pkgdir}${MINGW_PREFIX}"/share/zoneinfo ${_timezones[@]}
  zic -b fat -d "${pkgdir}${MINGW_PREFIX}"/share/zoneinfo/posix ${_timezones[@]}
  zic -b fat -d "${pkgdir}${MINGW_PREFIX}"/share/zoneinfo/right -L leapseconds ${_timezones[@]}
  # This creates the posixrules file. We use New York because POSIX requires the daylight savings time rules to be in accordance with US rules.
  zic -b fat -d "${pkgdir}${MINGW_PREFIX}"/share/zoneinfo -p America/New_York
  install -m444 -t "${pkgdir}${MINGW_PREFIX}"/share/zoneinfo iso3166.tab leap-seconds.list leapseconds tzdata.zi zonenow.tab zone1970.tab zone.tab SECURITY # zone.tab is depricated and will go soon

  # install license
  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}"/share/licenses/${_realname}/LICENSE
}
