# Maintainer: Jeremy Drake <github@jdrake.com>

pkgname=(pacutils pacutils-devel)
pkgver=0.14.0
pkgrel=2
pkgdesc="Utility library for libalpm front-ends (MSYS2 port)"
arch=('i686' 'x86_64')
url="https://github.com/andrewgregory/pacutils"
license=('MIT')
depends=('gcc-libs'
         'libarchive'
         'libcurl'
         'libgpgme'
         'libiconv'
         'libopenssl'
         'pacman')
makedepends=('libarchive-devel'
             'libcurl-devel'
             'libgpgme-devel'
             'perl'
             'make'
             'pkgconf'
             'gcc')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/andrewgregory/${pkgname}/archive/refs/tags/v${pkgver}.tar.gz"
        "0003-msysize.patch")
sha256sums=('b5d9be8472afea7ae43a0f15492eb3dce4bf768e0d2bb35284b5e1425ecd3849'
            'ad5f1aceee99a56f6ff39aaa03fabf99df7d5f6cdca60d842054f07754c44ab5')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  patch -Np1 -i "${srcdir}/0003-msysize.patch"
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make all doc PREFIX=/usr LOCALSTATEDIR=/var SYSCONFDIR=/etc SOPREFIX=msys- SOEXT=dll
  make -j1 DESTDIR="${srcdir}/prefix-${CARCH}" install PREFIX=/usr LOCALSTATEDIR=/var SYSCONFDIR=/etc SOPREFIX=msys- SOEXT=dll
}

check() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make check PREFIX=/usr LOCALSTATEDIR=/var SYSCONFDIR=/etc SOPREFIX=msys- SOEXT=dll
}

package_pacutils() {
  cd "${srcdir}"

  cp -fR "${srcdir}/prefix-${CARCH}/"* "${pkgdir}"
  rm -rf "${pkgdir}/usr/"{include,lib,share/man/man3}
}

package_pacutils-devel() {
  cd "${srcdir}"

  mkdir -p "${pkgdir}/usr/share/man"
  cp -fR "${srcdir}/prefix-${CARCH}/usr/"{include,lib} "${pkgdir}/usr/"
  cp -fR "${srcdir}/prefix-${CARCH}/usr/share/man/man3" "${pkgdir}/usr/share/man/"
}
