# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname=XML-Parser
pkgname=perl-${_realname}
pkgver=2.58
pkgrel=1
pkgdesc="Expat-based XML parser module for perl"
arch=('i686' 'x86_64')
license=('spdx:GPL-1.0-only' 'spdx:Artistic-1.0-Perl')
url="https://metacpan.org/dist/XML-Parser"
msys2_repository_url='https://github.com/cpan-authors/XML-Parser'
msys2_changelog_url='https://github.com/cpan-authors/XML-Parser/blob/main/Changes'
msys2_references=(
  "purl: pkg:cpan/TODDR/XML-Parser"
)
groups=('perl-modules')
depends=('perl' 'libexpat' 'perl-File-ShareDir')
makedepends=('libexpat-devel' 'perl-devel' 'perl-File-ShareDir-Install' 'make' 'gcc')
replaces=('perlxml')
provides=("perlxml=${pkgver}")
options=('!emptydirs')
source=("https://cpan.metacpan.org/authors/id/T/TO/TODDR/${_realname}-${pkgver}.tar.gz")
sha256sums=('8e0bd510a6095374aff14e4f0cea62c40df5c434ac703850f20ae8edb2c9b100')

prepare() {
  cd "${srcdir}/${_realname}-${pkgver}"
}

build() {
  cd "${srcdir}/${_realname}-${pkgver}"

  # install module in vendor directories.
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd "${srcdir}/${_realname}-${pkgver}"
  make test
}

package() {
  cd "${srcdir}/${_realname}-${pkgver}"
  make install DESTDIR="${pkgdir}"

  # remove perllocal.pod and .packlist.
  find "${pkgdir}" -name perllocal.pod -delete
  find "${pkgdir}" -name .packlist -delete

  # fix permissions
  find ${pkgdir}/usr -type f -name *.dll | xargs chmod 0755
}
