# Maintainer: David Mott <mott.david.j@gmail.com>
# Contributor: Niklas Holm <jadedcyborg@gmail.com>

pkgname='parallel'
pkgver=20260422
pkgrel='2'
pkgdesc="A shell tool for executing jobs in parallel"
arch=('any')
url='https://www.gnu.org/software/parallel/'
msys2_references=(
  "cpe: cpe:/a:gnu:parallel"
)
license=('GPL3')
depends=('perl')
makedepends=('autotools')
source=("https://ftpmirror.gnu.org/gnu/${pkgname}/${pkgname}-${pkgver}.tar.bz2"{,".sig"}
        "0001-support-MSys2.patch"
        "0002-hardcode-real-max-length-32000.patch")
validpgpkeys=('CDA01A4208C4F74506107E7BD1AB451688888888')
sha256sums=('664cf165d66ea217b2f49cd96a7865ecf90c9d0616599cc2aba8cad481d907bb'
            'SKIP'
            '7f52adb70a5bbd0195652df913267144f654abef85e6e0b0c80cc9466c98565f'
            'eb5490c025dc37cf40fe7a3bde71602f5c6a28fd341ded1537a84281d1eb8e2b')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -p1 -i "${srcdir}/0001-support-MSys2.patch"
  patch -p1 -i "${srcdir}/0002-hardcode-real-max-length-32000.patch"

  # ACLOCAL_PATH is needed to pick up local m4 macro
  ACLOCAL_PATH="${srcdir}/${pkgname}-${pkgver}" autoreconf -vif
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure \
    --build="${CHOST}" \
    --host="${CHOST}" \
    --target="${CHOST}" \
    --prefix="/usr"
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}
