# Maintainer: David Mott <mott.david.j@gmail.com>
# Contributor: Niklas Holm <jadedcyborg@gmail.com>

pkgname='parallel'
pkgver=20260422
pkgrel='1'
pkgdesc="A shell tool for executing jobs in parallel"
arch=('any')
url='https://www.gnu.org/software/parallel/'
msys2_references=(
  "cpe: cpe:/a:gnu:parallel"
)
license=('GPL3')
depends=('perl')
makedepends=('autotools')
source=("https://ftpmirror.gnu.org/gnu/${pkgname}/${pkgname}-${pkgver}.tar.bz2"{,".sig"})
validpgpkeys=('CDA01A4208C4F74506107E7BD1AB451688888888')
sha256sums=('664cf165d66ea217b2f49cd96a7865ecf90c9d0616599cc2aba8cad481d907bb'
            'SKIP')

prepare() {
    cd "${srcdir}/parallel-${pkgver}"
    sed -i '15333,15339c\
sub real_max_length() {\
    return 32000;\
}\
# Patched for MSYS2' src/parallel
    sed -i '1s|#!/usr/bin/env perl|#!/usr/bin/perl|' src/parallel
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure \
    --build="${CHOST}" \
    --host="${CHOST}" \
    --target="${CHOST}" \
    --prefix="/usr"
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}
