
_realname=brush
pkgbase=mingw-w64-${_realname}
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
pkgver=0.4.0
pkgrel=2
pkgdesc="Bash-compatible shell"
arch=('any')
mingw_arch=('ucrt64' 'clang64' 'clangarm64')
url="https://github.com/reubeno/brush"
msys2_repository_url="${url}"
msys2_references=(
  'archlinux: brush'
)
license=('spdx:MIT')
makedepends=("${MINGW_PACKAGE_PREFIX}-rust")
options=('!strip') # part of Cargo.toml
source=("${url}/archive/${_realname}-shell-v${pkgver}.tar.gz"
"${url}/releases/download/${_realname}-shell-v${pkgver}/${_realname}-docs.tar.gz"
)
sha256sums=('0cce607454972c18bc4a30d2f44a2c91fccf02c458475fda7720370a3dc8a4f0'
            '1070fa3a9470927c0c3d9c5417151f1b8f72317b42bed21f33e5fd4f3dad3332')

prepare() {
  cd "${_realname}-${_realname}-shell-v$pkgver"
  cargo fetch --locked --target "${RUST_CHOST}"
}

build() {
  cd "${_realname}-${_realname}-shell-v$pkgver"
  cargo build --release --frozen
}

package() {
  cd "${_realname}-${_realname}-shell-v$pkgver"
  install -Dm 755 "target/release/$_realname" -t "${pkgdir}${MINGW_PREFIX}/bin"
  install -Dm 644 README.md -t "${pkgdir}${MINGW_PREFIX}/share/doc/$_realname"
  install -Dm 644 LICENSE -t "${pkgdir}${MINGW_PREFIX}/share/licenses/$_realname"
  install -Dm644 "${srcdir}/man/${_realname}.1" -t "${pkgdir}${MINGW_PREFIX}/share/man/man1"
}
