# Maintainer: Christoph Reiter <reiter.christoph@gmail.com>

pkgbase=autotools-wrappers
pkgname=('automake-wrapper' 'autoconf-wrapper' )
pkgver=20260320
pkgrel=1
arch=('any')
makedepends=('git')
url="https://gitweb.gentoo.org/proj/autotools-wrappers.git/"
msys2_repository_url='https://github.com/gentoo/autotools-wrappers'
license=('spdx:GPL-2.0-only')
source=("git+https://github.com/gentoo/autotools-wrappers#tag=at-${pkgver}")
sha256sums=('ed7e3d25d25cba5e45f8668d1f1938355e31e20ecb66d82e7b556ef402d7da17')

prepare() {
  cd "${srcdir}/${pkgbase}"
}

package_automake-wrapper() {
  pkgdesc="Wrapper scripts for automake commands"
  depends=(
    'bash'
    'gawk'
    'automake1.11'
    'automake1.12'
    'automake1.13'
    'automake1.14'
    'automake1.15'
    'automake1.16'
    'automake1.17'
    'automake1.18')
  provides=("automake")
  conflicts=("automake")

  mkdir -p ${pkgdir}/usr/bin
  for prog in automake aclocal
  do
    cp "${srcdir}/${pkgbase}/am-wrapper.sh" "${pkgdir}/usr/bin/${prog}"
  done
}

package_autoconf-wrapper() {
  pkgdesc="Wrapper scripts for autoconf commands"
  depends=(
    'bash'
    'sed'
    'autoconf2.73'
    'autoconf2.72'
    'autoconf2.71'
    'autoconf2.69'
    'autoconf2.13')
  provides=("autoconf")
  conflicts=("autoconf")
  replaces=("autoconf")

  mkdir -p ${pkgdir}/usr/bin
  for prog in autoconf autoheader autom4te autoreconf autoscan autoupdate ifnames
  do
    cp "${srcdir}/${pkgbase}/ac-wrapper.sh" "${pkgdir}/usr/bin/${prog}"
  done
}
