_realname='tetgen'
pkgbase=mingw-w64-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
pkgver=1.6.0
pkgrel=3
pkgdesc='A Quality Tetrahedral Mesh Generator and a 3D Delaunay Triangulator (mingw-w64)'
arch=('any')
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64' 'clang32')
depends=("${MINGW_PACKAGE_PREFIX}-gcc-libs")
makedepends=("${MINGW_PACKAGE_PREFIX}-ninja"
             "${MINGW_PACKAGE_PREFIX}-cmake"
             "${MINGW_PACKAGE_PREFIX}-cc")
url='https://wias-berlin.de/software/index.jsp?id=TetGen&lang=1'
license=('AGPL3')
source=(http://www.tetgen.org/1.5/src/${_realname}${pkgver}.tar.gz
        "0001-fix-missing-install.patch")
sha256sums=('87b5e61ebd3a471fc4f2cdd7124c2b11dd6639f4feb1f941a5d2f5110d05ce39'
            'aa8eeec123915754e32aad056e4feb02dee5bc626f84918a029bdd9fbd200aac')

prepare() {
  cd "${srcdir}/${_realname}${pkgver}"

  patch -Np1 -i "${srcdir}"/0001-fix-missing-install.patch
}

build() {
  [[ -d "${srcdir}/build-${MSYSTEM}" ]] && rm -rf "${srcdir}/build-${MSYSTEM}"
  mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"

  declare -a extra_config
  if check_option "debug" "n"; then
    extra_config+=("-DCMAKE_BUILD_TYPE=Release")
  else
    extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
  fi

  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
    ${MINGW_PREFIX}/bin/cmake \
    -GNinja \
    -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
    "${extra_config[@]}" \
  ../"${_realname}${pkgver}"

  ${MINGW_PREFIX}/bin/cmake --build .
}

package() {
  cd "${srcdir}/build-${MSYSTEM}"

  DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/cmake --install .
  install -m 644 -D -t "${pkgdir}${MINGW_PREFIX}/lib" libtet.a
  install -m 644 -D -t "${pkgdir}${MINGW_PREFIX}/include" ../"${_realname}${pkgver}/tetgen.h"
}
