# Contributor (MSYS2): Oleg A. Khlybov <fougas@mail.ru>

_realname=libomemo-c
pkgbase=mingw-w64-${_realname}
pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
pkgver=0.5.1
pkgrel=1
pkgdesc='Fork of libsignal-protocol-c adding support for OMEMO XEP-0384 0.5.0+ (mingw-w64)'
arch=('any')
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
url='https://github.com/dino/libomemo-c'
msys2_repository_url="https://github.com/dino/libomemo-c"
msys2_references=(
  'archlinux: libomemo-c'
)
license=('spdx:GPL-3.0')
depends=("${MINGW_PACKAGE_PREFIX}-cc-libs"
         "${MINGW_PACKAGE_PREFIX}-protobuf-c")
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
             "${MINGW_PACKAGE_PREFIX}-protobuf"
             "${MINGW_PACKAGE_PREFIX}-meson")
source=(https://github.com/dino/libomemo-c/releases/download/v${pkgver}/${_realname}-${pkgver}.tar.gz)
sha256sums=('766827c07ff2cdc4deaf87bd9485474ed4aeea2fa5152593bf49fabe22b5865f')

build() {
  mkdir -p "build-${MSYSTEM}"
  cd "build-${MSYSTEM}"

  MSYS2_ARG_CONV_EXCL="--prefix=" \
  meson setup \
    --prefix="${MINGW_PREFIX}" \
    -Dtests=false \
    ../${_realname}-${pkgver}

  meson compile
}

package() {
  cd "${srcdir}/build-${MSYSTEM}"

  DESTDIR="${pkgdir}" meson install
}
