# Maintainer: J. Peter Mugaas <jpmugaas@suddenlink.net>

_realname=libimagequant
pkgbase=mingw-w64-${_realname}2
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}2")
pkgver=2.17.0
pkgrel=3
pkgdesc="Palette quantization library (mingw-w64)"
arch=('any')
mingw_arch=('clang32' 'clangarm64')
url='https://github.com/ImageOptim/libimagequant'
license=("GPL3" "MIT")
provides=("${MINGW_PACKAGE_PREFIX}-${_realname}")
conflicts=("${MINGW_PACKAGE_PREFIX}-${_realname}")
replaces=("${MINGW_PACKAGE_PREFIX}-${_realname}")
makedepends=("${MINGW_PACKAGE_PREFIX}-autotools" "${MINGW_PACKAGE_PREFIX}-cc")
source=("${_realname}-${pkgver}.tar.gz"::"https://github.com/ImageOptim/${_realname}/archive/${pkgver}.tar.gz")
sha256sums=('9f6cc50182be4d2ece75118aa0b0fd3e9bbad06e94fd6b9eb3a4c08129c2dd26')

prepare() {
  cd $srcdir/${_realname}-${pkgver}
}

build() {
  cd "$srcdir"/${_realname}-${pkgver}
  rm -rf "${srcdir}"/build-${MSYSTEM} || true
  cp -r "${srcdir}/${_realname}-${pkgver}" "${srcdir}/build-${MSYSTEM}"
  cd "${srcdir}"/build-${MSYSTEM}

  ./configure --prefix=${MINGW_PREFIX} \
    CC="${MINGW_PREFIX}/bin/cc" \
    --disable-sse

  make --jobs=1 static dll imagequant.pc
}

package() {
  cd "${srcdir}"/build-${MSYSTEM}
   mkdir -p ${pkgdir}${MINGW_PREFIX}/bin
   mkdir -p ${pkgdir}${MINGW_PREFIX}/lib/pkgconfig
   mkdir -p ${pkgdir}${MINGW_PREFIX}/include
   mkdir -p ${pkgdir}${MINGW_PREFIX}/share/doc/libimagequant
   mkdir -p ${pkgdir}${MINGW_PREFIX}/share/licenses/libimagequant
   install -m 0644 -p imagequant.dll \
     ${pkgdir}${MINGW_PREFIX}/bin/imagequant.dll
   install -m 0644 -p libimagequant.a \
     ${pkgdir}${MINGW_PREFIX}/lib/libimagequant.a
   install -m 0644 -p imagequant_dll.a \
     ${pkgdir}${MINGW_PREFIX}/lib/libimagequant.dll.a
   install -m 0644 -p libimagequant.h \
      ${pkgdir}${MINGW_PREFIX}/include/libimagequant.h
   install -m 0644 -p imagequant.pc \
       ${pkgdir}${MINGW_PREFIX}/lib/pkgconfig/imagequant.pc
   install -m 0644 -p CHANGELOG \
      ${pkgdir}${MINGW_PREFIX}/share/doc/libimagequant/CHANGELOG
   install -m 0644 -p README.md \
      ${pkgdir}${MINGW_PREFIX}/share/doc/libimagequant/README.md
   install -m 0644 -p COPYRIGHT \
       ${pkgdir}${MINGW_PREFIX}/share/licenses/libimagequant/COPYRIGHT
}

