_realname=calceph
pkgbase=mingw-w64-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
pkgver=3.5.5
pkgrel=1
pkgdesc='The CALCEPH Library is designed to access the binary planetary ephemeris files, such INPOPxx and JPL DExxx ephemeris files (mingw-w64)'
url='https://www.imcce.fr/inpop/calceph'
license=('spdx:CECILL-C OR CECILL-B OR CECILL-2.1')
arch=('any')
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
depends=("${MINGW_PACKAGE_PREFIX}-gcc-libs"
         $([[ ${MINGW_PACKAGE_PREFIX} == *-clang-* ]] || echo "${MINGW_PACKAGE_PREFIX}-gcc-libgfortran")
)
makedepends=("${MINGW_PACKAGE_PREFIX}-autotools"
             "${MINGW_PACKAGE_PREFIX}-cc"
             $([[ ${MINGW_PACKAGE_PREFIX} == *-clang-* ]] || echo "${MINGW_PACKAGE_PREFIX}-fc")
)
source=("https://www.imcce.fr/content/medias/recherche/equipes/asd/calceph/${_realname}-${pkgver}.tar.gz")
sha256sums=('f7acf529a9267793126d7fdbdf79d4d26ae33274c99d09a9fc9d6191a3c72aca')

build() {
  mkdir -p "${srcdir}/build-${MSYSTEM}" && cd "${srcdir}/build-${MSYSTEM}"
 
  declare -a _extra_config
  [[ ${MINGW_PACKAGE_PREFIX} == *-clang-* ]]  && _extra_config+=("--enable-fortran=no")

  ../${_realname}-${pkgver}/configure \
    --prefix=${MINGW_PREFIX} \
    --build=${MINGW_CHOST} \
    --host=${MINGW_CHOST} \
    --target="${MINGW_CHOST}" \
    FCFLAGS=-J../src ax_cv_f90_modext=mod      \
    ${_extra_config[@]} \
    --enable-static \
    --enable-shared
    make
}

check() {
    cd "${srcdir}/build-${MSYSTEM}"
    make check
}

package() {
   cd "${srcdir}/build-${MSYSTEM}"
    DESTDIR="${pkgdir}" make install 
    install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING_CECILL_B.LIB" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING_CECILL_B.LIB"
    install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING_CECILL_C.LIB" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING_CECILL_C.LIB"
    install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING_CECILL_V2.1.LIB" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING_CECILL_V2.1.LIB"
}
